Excel 中的条件判断类函数包括:
1、常用的 IF、SUMIF、COUNTIF、AVERAGEIF等函数。
2、Excel 2016 版以后新增多条件分支函数 IFS、SUMIFS、COUNTIFS、AVERAGEIFS 等。
3、根据表达式是否错误来作为条件的 IFERROR 函数。
4、根据公式是否找不到引用值来作为条件的 IFNA 函数。
IF 函数
IF(条件,A,B)
判断是否满足某个条件,如果满足则返回 A 值,如果不满足则返回 B 值。
IF 函数可以嵌套使用,比如:
IF(条件1,IF(条件2,A1,A2),B)
表示:
如果条件 1 为真,则返回第二个 IF 函数的返回值 A1(条件 2 为真时)或 A2 (条件 2 为假时),否则返回值 B。
例如:
=IF(K2>89,"A",IF(K2>79,"B",IF(K2>69,"C",IF(K2>59,"D","F"))))
提示:
IF 函数最多可嵌套 64 层。嵌套的 IF 函数只能在编辑栏中输入。
IFS 函数
IFS 函数允许测试最多 127 个不同的条件。但不建议在 IF 或 IFS 语句中嵌套过多条件。
IFS(条件1,A1,[条件2,A2,条件3,A3,]...)
表示:
如果首先满足条件 1,则返回值 A1;如果首先满足条件 2,则返回值 A2 等等,即,返回多个条件中首先满足的那个对应的值。
例如:
=IFS(A2>89,"A",A2>79,"B",A2>69,"C",A2>59,"D",TRUE,"F")
说明:
1、若要指定默认结果,即确定当前所有条件都不满足时返回的值,应该将最后一个条件 N 设为 TRUE(真),并给出默认结果 An。
2、如果找不到为 TRUE(真)的条件,则此函数返回 #N/A! 错误。
IFERROR 函数
IFERROR(表达式,A)
如果表达式有错误,则返回一个值 A。如果表达式是正确的,则返回表达式运算结果。
说明:
当表达式没有错误时,如果不想返回表达式的值而想返回另一个值时,需结合 IF 函数与 ISERROR 函数来实现:
IF(ISERROR(表达式),A,B)
即,当表达式出错时,则返回 A。表达式没错则返回 B。
IFNA函数
IFNA(表达式,A)
表示:
如果表达式解释为 #N/A ,则返回一个值 A。否则,返回表达式运算结果。
附:Excel 中常见的错误提示
####
说明单元格长度不够显示。
#VALUE!
说明值计算错误,用非数值参与计算。
#DIV/0!
说明除数是0。
#N/A
此错误的最常见的原因是公式找不到引用值,常在使用 VLOOUP、HLOOKUP、LOOKUP 或 MATCH 等函数时出现。
#NAME?
公式名称中存在拼写错误,表明语法中的某些内容需要更正。
#NULL!
如果在公式中使用了不正确的区域运算符,或者在区域引用之间使用了交叉运算符(空格字符)来指定不相交的两个区域的交集,将显示此错误。
#NUM!
公式或函数中使用无效数值时,比如,对负数开平方根。或者,数值所用数据类型或数字格式不受支持时,通常会出现此错误。
#REF!
当单元格引用无效时,比如当删除了由其它公式引用的单元格,或将移动单元格粘贴到由其它公式引用的单元格中,就会提示错误值 #REF!。
COUNTIF 与 COUNTIFS 函数
COUNTIF 函数语法:
COUNTIF(区域A,条件)
计算区域 A 中满足给定条件的单元格数目。
比如,统计等级为 A 的人数的公式:
=COUNTIF($L$2:$L$15,"=A")
COUNTIFS 函数语法:
COUNTIFS(区域A,条件A,[区域B,条件B,]...)
统计在区域 A 中满足条件 A,并且在区域 B 中满足条件 B 的单元格数。
说明:
1、区域 A 以后的区域,比如区域 B、区域 C 等必须与区域 A 具有相同的行数和列数。这些区域无需彼此相邻。
2、可在条件中使用通配符:? 和 * 。?号匹配任意单个字符,* 号匹配任意字符串。
SUMIF 与 SUMIFS 函数
SUMIF 函数语法 1:
SUMIF(求和区域,条件)
对求和区域中满足条件的单元格求和。
比如,统计已销售数量超过 10 的总量:
=SUMIF(A2:A9,">10")
SUMIF 函数语法 2:
SUMIF(条件区域,条件,求和区域)
对条件区域中满足条件的单元格对应求和区域的对应值进行求和。
比如,统计已销售香蕉、香梨的数量:条件区域为产品列,求和区域为已销售数量列:
=SUMIF(B2:B9,"=香*",A2:A9)
SUMIFS 函数语法:
SUMIFS(要求和的区域A,条件区域A,条件A,条件区域B,条件B...)
对求和区域的数值进行求和,不过它们需要满足不同条件区域的不同条件。
比如,统计卢宁的已销售香蕉、香梨的数量:要求和的区域是“已销售数量”,要求和的数据必须满足:1、产品为香蕉、香梨;2、销售人员为卢宁。
=SUMIFS(A2:A9,B2:B9,"=香*",C2:C9,"卢宁")
AVERAGEIF 与 AVERAGEIFS 函数
对指定区域中满足条件的单元格求算术平均值。语法与上面一组函数类似。
AVERAGEIF 函数语法:
AVERAGEIF(求平均值的区域,条件)
AVERAGEIF(条件区域,条件,求平均值的区域)
AVERAGEIFS 函数语法:
AVERAGEIFS(要求平均值的区域A,条件区域A,条件A,条件区域B,条件B,...)
“有钱的捧个钱场,好看的点下在看”
更多推荐
Excel:IF 条件类函数
发布评论