批处理一键创建局域网共享文件夹或文件共享轻松访问Win系统其他电脑的共享文件命令行（纯bat代码）实用便携~

　　说到文件夹共享很多朋友都知道了，直接右键共享就是了，方法网上就很多教程，但是如果有大批量的电脑需要共享，手工一个一个的去开启，就有点麻烦了，而且还要记录创建指定的共享名称，建立固定的共享通道，费事费力，有没有什么办法一键完成呢？当然有，来看看如何用批处理命令来实现快速创建和访问共享文件夹。先说一下创建文件夹共享代码：

@echo off
rem 先开启系统的网络发现和局域网文件共享防火墙权限
netsh advfirewall firewall set rule group="文件和打印机共享" new enable=yes >nul
netsh advfirewall firewall set rule group="网络发现" new enable=yes >nul
netsh firewall set service type = fileandprint mode = enable scope = subnet >nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa" /v "LimitBlankPasswordUse" /t REG_DWORD /d "00000000" /f >nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v "LimitBlankPasswordUse" /t REG_DWORD /d "00000000" /f >nul
rem 例看D盘下Ys文件夹里面有没有123文件夹，有则继续，没有创建一个
if not exist D:\Ys\123 md D:\Ys\123 >nul
rem 创建共享名为123且路径为D:\Ys\123的文件夹共享
net share 123=D:\Ys\123 /unlimited /cache:no /grant:everyone,full >nul
rem 调用cacls命令给D:\Ys\123文件增加可编辑的everyone所有共享权限
echo y|cacls D:\Ys\123 /t /c /p everyone:f >nul
rem 打开共享的文件夹并提示共享文件夹创建成功
start \\%Computername%\123 >nul
mshta vbscript:msgbox("　共享文件夹创建成功",64,"提示")(window.close)

　　这样共享就可以一键创建完成了，右键以管理员身份运行即可，这里需要注意一下，如果你修改的路径里面有空格，两边加上英文的双引号即可。

　　那局域网电脑如何访问该共享文件夹呢？其实有多种方法可以访问的，说一下常见的三种。

　　如果两边电脑都已经开网络共享权限了的话，直接点开【网络】在所有显示的局域网电脑列表中找到创建123共享的计算机名，如PC2021090128点进去就能看到123共享文件夹了。

　　或者打开运行对话框，如输入【\\PC2021090128\123】回车即可打开，也可以打开 \\计算机名 后在123文件夹上右键创建打开快捷方式到桌面或做映射盘符也可以，这样访问比较省事，注：这里\\PC2021090128就是创建123共享的电脑名。

　　删除共享的命令就比较简单了，直接用下面的就行了。

@echo off
rem 删除共享的文件夹命令
net share "123" /y /del
mshta vbscript:msgbox("　共享文件夹删除成功",64,"提示")(window.close)

　　因为前两种都要求必须电脑已开免密来宾共享权限了才能访问，不然就要输入创建共享电脑的登陆账号和密码才能访问，如果共享电脑的名称不经常变动的话，可以创建一个快速访问的方法，代码如下。

@echo off
rem 如PC2021090128就是创建共享的那台电脑名，12345678是开机密码，账号名是Administrator
net use \\PC2021090128\ipc$ "12345678" /user:"Administrator"
rem 最后用start命令打开看一下是否能够正常访问前面创建的文件夹共享
start \\PC2021090128\123

　　这个可以根据实际情况改动一下即可，start \\PC2021090128\123就是打开PC2021090128电脑上共享的123文件夹。可以把这个程序放到优盘或局域网内任意电脑上执行即可访问共享，不用再输账号和密码了，节省时间，感觉实用的朋友请点赞支持我，谢谢。